Internet Pratica/IPRAT_01.iso/SQL/ariacom/br15Evaluation.exe/br15Evaluation/ASP SCripts/vbMainParse.asp

Text File | 2002-09-09 | 6KB | 197 lines

<%
'
'  Ariacom Business Reports
'  Copyright 2001-2002, ARIACOM SARL, Geneva, Switzerland
'  All rights reserved
'  www.ariacom.com
'

'
'
'processElement
'
sub processElement(theNode)
  ' Display value of the node
  select case theNode.nodeName
  case kXml_TagItem
    processSubNodes theNode

  case kXml_TagItemDisplay
    itemDisplay theNode

  case kXml_TagItemString
    itemStringDisplay theNode

  case kXml_TagItemMultiString
    itemMultiStringDisplay theNode

  case kXml_TagItemEnum
    itemEnumDisplay theNode

  case kXml_TagItemBoolean
    itemBooleanDisplay theNode

  case kXml_TagItemNumeric
    itemNumericDisplay theNode

  case kXml_TagActionSubmit
    itemActionSubmitDisplay theNode

  case kXml_TagActionLink
    itemActionLinkDisplay theNode

  case else
    processSubNodes theNode
  end select

end sub

'
'processSubNodes
'
sub processSubNodes(theNode)
  ' Parse the sub nodes
  dim nodeListValue
  set nodeListValue = theNode.childNodes
  dim i
  for i = 0 to (nodeListValue.length -1)
    processNode nodeListValue.nextNode
  next
end sub


'
'processNode
'
sub processNode(theNode)
  'brDebug "processNode:" & theNode.nodeTypeString & " " & theNode.nodeName
  select case theNode.nodeTypeString
  case "element"
    'First we set that attribute id with the complete path
    dim newId
    newId = theNode.getAttribute(kXml_AttributeDataTag) & theNode.getAttribute(kXml_AttributeId)
    if newId <> "" then
      call theNode.setAttribute(kXml_AttributeId, newId)
    end if

    if gStrPresentationFunction <> "" then execute gStrPresentationFunction &" true,theNode"
    processElement theNode
    if gStrPresentationFunction <> "" then execute gStrPresentationFunction &" false,theNode"

  case "cdatasection" 'Probably direct HTML output
    Response.Write theNode.text

  case "document" 'Main document
    processSubNodes theNode

  case "cdatasection" 'Data section, we write directly to the Response
    response.write theNode.text
  end select
end sub

'
'main
'
sub main(theNode)
  dim parseItemArray(15) '15 items max
  dim parseItemLength
  dim startHTML, stopHTML
  dim ii, jj
  dim nodeList

  'overwrite action and ident if necessary
  dim hh, infoNode, infoNodeList, currentInfoNode
  set infoNode = theNode.selectNodes(".//item[@id=""" & kGenItemIdInformation & """]")
  if infoNode.Length > 0 then
    set infoNodeList = infoNode.item(0).childNodes
    for hh=0 to (infoNodeList.length - 1)
      set currentInfoNode = infoNodeList.nextNode
      if currentInfoNode.getAttribute(kXml_AttributeId) = kXml_TagRequestAction then
        gstrAction = currentInfoNode.text
      end if
      if currentInfoNode.getAttribute(kXml_AttributeId) = kXml_TagRequestIdent then
        gstrIdent = currentInfoNode.text
      end if
      if currentInfoNode.getAttribute(kXml_AttributeId) = kXml_TagRequestParameter then
        gstrParam = currentInfoNode.text
      end if
    next
  end if
  'get document informations
  set infoNode = theNode.selectNodes(".//item[@id=""" & kGenItemIdDocumentInformation & """]")
  if infoNode.Length > 0 then
    set infoNodeList = infoNode.item(0).childNodes
    for hh=0 to (infoNodeList.length - 1)
      set currentInfoNode = infoNodeList.nextNode
      if currentInfoNode.getAttribute(kXml_AttributeId) = kXml_TagDocumentType then
        gStrDocumentType = currentInfoNode.text
      end if
      if currentInfoNode.getAttribute(kXml_AttributeId) = kXml_TagDocumentCharSet then
        gStrDocumentCharSet = currentInfoNode.text
      end if
      if currentInfoNode.getAttribute(kXml_AttributeId) = kXml_TagDocumentTitle then
        gStrDocumentTitle = currentInfoNode.text
      end if
    next
  end if


  'handle document type
  if gStrDocumentType = "" then  gStrDocumentType = "text/html"
  Response.ContentType = gStrDocumentType

  if gStrDocumentType = "text/html" and gStrAction <> kAction_RepViewFile and gStrAction <> kAction_RepExecWithLogout then 'HTML
    addJavaScripts() 'java scripts is added here

    Response.Write("<html><head>")
    'handle charset
    if gStrDocumentCharset <> "" then
      Response.Write("<meta http-equiv=""Content-Type"" content=""charset=" & gStrDocumentCharset & """>")
    end if


    'add meta info for css
    Response.Write("<META http-equiv=""Content-Style-Type"" content=""text/css"">")
    Response.Write("<LINK href=""reportStyle.inc"" rel=styleSheet type=text/css>")
    'handle title
    if gStrDocumentTitle <> "" then
      Response.Write("<title>" & gStrDocumentTitle & "</title>")
    end if
    'style is specified here
    Response.Write("<style>a:hover {color: #FF0000;text-decoration:underline;}</style>")
    Response.Write("</head>")

    ' initialize defaults and presentation data
    call setDefaultPresentationValues()
    call initPresentationContext(parseItemArray, parseItemLength, startHTML, stopHTML)

    Response.Write startHTML
    for ii=0 to (parseItemLength-1)
      'select the items to parse
      set nodeList = theNode.selectNodes(parseItemArray(ii))
      'brDebug parseItemArray(ii) & " result:" & CStr(nodeList.Length)
      for jj=0 to (nodeList.Length-1)
        processNode nodeList.item(jj)
      next
    next
    Response.Write stopHTML
    Response.Write("</html>")
  else
    'other type, no html at all
    set nodeList = theNode.selectNodes(".//item[@id=""" & kGenItemIdMain & """]")
    for jj=0 to (nodeList.Length-1)
      processNode nodeList.item(jj)
    next
  end if

  'Do not keep the session in following cases
  if gStrAction = kAction_MainLoginWindow or gStrAction = kAction_MainLogout or gStrAction = kAction_MainErrorWithLogout or gStrAction = kAction_RepExecWithLogout or gStrAction = kAction_RepExecOutputWithLogout then
    'brDebug "Abandon: " & Session.SessionID
    set Session("reportServer") = nothing
    Session.Abandon
  end if
end sub
%>